9:11 p.m.
Hello all,
I did a search on google and I have also done a search from within the forum list and
couldn't find an answer to my question; nonetheless, please forgive me if this is
posted elsewhere.
I am looking for a way to overlay the histograms of two variables in order to provide a
visual comparison in a paper I'm writing.
Here's an example of a blog post describing something similar using R:
https://www.spsanderson.com/steveondata/posts/2023-09-15/index.html
I have done this in R (I suppose I can export the work natively from within gretl), but
let's be honest -- gnuplot is as good as it gets and I'd prefer to put my graphs
together from within gretl.
As always, any help is appreciated.
Best,
Chris L.
10:28 p.m.
Am 16.06.2024 um 23:11 schrieb climnios(a)providence.edu:
Hello all,
I did a search on google and I have also done a search from within the forum list and
couldn't find an answer to my question; nonetheless, please forgive me if this is
posted elsewhere.
I am looking for a way to overlay the histograms of two variables in order to provide a
visual comparison in a paper I'm writing.
I'm not aware of something that does exactly this; close substitutes
might be the following:
- Use the built-in boxplots: there you can specify several variables and
they are shown side by side. (Although, to be honest, the plot design
does not look super hot.)
- Overlay the smoothed histogram a.k.a. the kernel density estimate.
Example:
<hansl>
open mrw list L = gdpgrow popgrow matrix dens = kdensity(L) gnuplot 2 3
1 --matrix=dens --with-lines --fit=none --output=display
</hansl>
cheers
sven
11:29 p.m.
Thanks, Sven. I will try the code you've provided in the console.
Upon further digging, I found the following on stackoverflow re gnuplot:
https://stackoverflow.com/questions/50338019/gnuplot-histogram-chart-with...
Can the code on that stackoverflow page somehow be mapped into something the gnuplot under
the hood of gretl will understand?
6:02 a.m.
On 17/06/2024 01:29, climnios(a)providence.edu wrote:
Thanks, Sven. I will try the code you've provided in the
console.
Upon further digging, I found the following on stackoverflow re gnuplot:
https://stackoverflow.com/questions/50338019/gnuplot-histogram-chart-with...
Can the code on that stackoverflow page somehow be mapped into something the gnuplot
under the hood of gretl will understand?
Is this close to what you need?
<hansl>
function void multi_hist(list L)
n = nelem(L)
vn = varnames(L)
mh = ""
outfile --buffer=mh
printf "set style fill solid 0.5\n"
printf "set style data histogram \n"
printf "set style histogram clustered\n"
strings names = array(n)
loop foreach i L
names[i] = "hist" ~ "$i"
freq $i --quiet --silent
f = $result
cnameset(f, "")
printf "$%s << EOD\n", names[i]
printf "%12.4f", f
printf "EOD\n\n"
endloop
printf "plot "
loop i = 1 .. n
printf "$%s using 2 t \"%s\"", names[i], vn[i]
if i == n
printf "\n"
else
printf ", "
endif
endloop
end outfile
gnuplot --inbuf=mh --output=display
end function
### example
open mroz87.gdt
list L = HE WE
multi_hist(L)
</hansl>
-------------------------------------------------------
Riccardo (Jack) Lucchetti
Dipartimento di Scienze Economiche e Sociali (DiSES)
Università Politecnica delle Marche
(formerly known as Università di Ancona)
r.lucchetti(a)univpm.it
http://www2.econ.univpm.it/servizi/hpp/lucchetti
-------------------------------------------------------
6:35 a.m.
On 17/06/2024 08:02, Riccardo (Jack) Lucchetti wrote:
On 17/06/2024 01:29, climnios(a)providence.edu wrote:
> Thanks, Sven. I will try the code you've provided in the console.
>
> Upon further digging, I found the following on stackoverflow re gnuplot:
> https://stackoverflow.com/questions/50338019/gnuplot-histogram-chart-with...
>
> Can the code on that stackoverflow page somehow be mapped into
> something the gnuplot under the hood of gretl will understand?
Is this close to what you need?
I'm sorry, I hadn't thought of the possibility that the series may not
have the same support. Use the attached version instead.
PS: this script assumes that all the variable are discrete. For
continuous variable a different approach would be needed.
-------------------------------------------------------
Riccardo (Jack) Lucchetti
Dipartimento di Scienze Economiche e Sociali (DiSES)
Università Politecnica delle Marche
(formerly known as Università di Ancona)
r.lucchetti(a)univpm.it
http://www2.econ.univpm.it/servizi/hpp/lucchetti
-------------------------------------------------------
8:28 a.m.
Am 17.06.2024 um 08:35 schrieb Riccardo (Jack) Lucchetti:
On 17/06/2024 08:02, Riccardo (Jack) Lucchetti wrote:
>
> Is this close to what you need?
I'm sorry, I hadn't thought of the possibility that the series may not
have the same support. Use the attached version instead.
PS: this script assumes that all the variable are discrete. For
continuous variable a different approach would be needed.
This looks very nice, but indeed I'd say that a histogram (OP) refers to
continuous variables.
cheers
sven
9:43 a.m.
On 17/06/2024 10:28, Sven Schreiber wrote:
Am 17.06.2024 um 08:35 schrieb Riccardo (Jack) Lucchetti:
> On 17/06/2024 08:02, Riccardo (Jack) Lucchetti wrote:
>>
>> Is this close to what you need?
>
> I'm sorry, I hadn't thought of the possibility that the series may not
> have the same support. Use the attached version instead.
Further revision attached, where the labels on the x axis are handled
more sensibly.
> PS: this script assumes that all the variable are discrete. For
> continuous variable a different approach would be needed.
This looks very nice, but indeed I'd say that a histogram (OP) refers to
continuous variables.
Possibly. That would require a completely different approach, though. In
those cases, I'd think kernel density estimates would be more advisable.
-------------------------------------------------------
Riccardo (Jack) Lucchetti
Dipartimento di Scienze Economiche e Sociali (DiSES)
Università Politecnica delle Marche
(formerly known as Università di Ancona)
r.lucchetti(a)univpm.it
http://www2.econ.univpm.it/servizi/hpp/lucchetti
-------------------------------------------------------
10:31 a.m.
On 17/06/2024 11:43, Riccardo (Jack) Lucchetti wrote:
On 17/06/2024 10:28, Sven Schreiber wrote:
> This looks very nice, but indeed I'd say that a histogram
(OP) refers
> to continuous variables.
Possibly. That would require a completely different approach, though. In
those cases, I'd think kernel density estimates would be more advisable.
I mean, something like this:
<hansl>
function void multi_density(list L)
n = nelem(L)
totrows = 0
matrices kd = array(n)
loop foreach i L
kd[i] = kdensity(L.$i)
totrows += rows(kd[i])
endloop
matrix X = mshape(NA, totrows, n+1)
k = 1
loop i = 1 .. n
nr = rows(kd[i])
X[k:k+nr-1, {n+1, i}] = kd[i]
k += nr
endloop
print X
cnameset(X, varnames(L) + defarray("x"))
gnuplot --matrix=X --with-lines --output=display
end function
open card_krueger94.gdt
list L = 23 24 42 43
multi_density(L)
</hansl>
-------------------------------------------------------
Riccardo (Jack) Lucchetti
Dipartimento di Scienze Economiche e Sociali (DiSES)
Università Politecnica delle Marche
(formerly known as Università di Ancona)
r.lucchetti(a)univpm.it
http://www2.econ.univpm.it/servizi/hpp/lucchetti
-------------------------------------------------------
10:54 a.m.
Am 17.06.2024 um 12:31 schrieb Riccardo (Jack) Lucchetti:
On 17/06/2024 11:43, Riccardo (Jack) Lucchetti wrote:
>
> Possibly. That would require a completely different approach, though.
> In those cases, I'd think kernel density estimates would be more
> advisable.
I mean, something like this:
...
loop foreach i L
kd[i] = kdensity(L.$i)
Did you see my previous code snippet? kdensity() accepts a list input,
it's pretty straightforward.
But still a histogram certainly has its role. The doc for the relevant
'freq' command mentions that the numerical histogram can be accessed via
$result. I guess that can be used (in a loop) to construct the needed
plot with your gnuplot magic. Right now I don't have time to look into
this further.
(Apart from the other thing that is mentioned in the freq doc, namely
that the aggregate() function can be used. That's certainly true, but it
doesn't give an example of how exactly. A challenge for you!?)
cheers
sven
12:03 p.m.
On 17/06/2024 12:54, Sven Schreiber wrote:
Am 17.06.2024 um 12:31 schrieb Riccardo (Jack) Lucchetti:
> On 17/06/2024 11:43, Riccardo (Jack) Lucchetti wrote:
>
>>
>> Possibly. That would require a completely different approach, though.
>> In those cases, I'd think kernel density estimates would be more
>> advisable.
>
> I mean, something like this:
> ...
> loop foreach i L
>
> kd[i] = kdensity(L.$i)
>
Did you see my previous code snippet? kdensity() accepts a list input,
it's pretty straightforward.
Ah cool, I didn't remember. Therefore, the example simplifies to:
<hansl>
function void multi_density(list L)
X = kdensity(L)
X = X[,2:] ~ X[,1]
cnameset(X, varnames(L) + defarray("x"))
gnuplot --matrix=X --with-lines --output=display
end function
open card_krueger94.gdt
list L = 23 24 42 43
multi_density(L)
</hansl>
But still a histogram certainly has its role. The doc for the
relevant
'freq' command mentions that the numerical histogram can be accessed via
$result. I guess that can be used (in a loop) to construct the needed
plot with your gnuplot magic. Right now I don't have time to look into
this further.
Up to a point, I'm afraid: the $result for continuous data gives you the
midpoint, but not the boundaries of the bin. And these can be different
from variable to variable, so that'd be tricky.
(Apart from the other thing that is mentioned in the freq doc, namely
that the aggregate() function can be used. That's certainly true, but it
doesn't give an example of how exactly. A challenge for you!?)
that's easy:
<hansl>
open mroz87.gdt
eval aggregate(const, WE)
</hansl>
-------------------------------------------------------
Riccardo (Jack) Lucchetti
Dipartimento di Scienze Economiche e Sociali (DiSES)
Università Politecnica delle Marche
(formerly known as Università di Ancona)
r.lucchetti(a)univpm.it
http://www2.econ.univpm.it/servizi/hpp/lucchetti
-------------------------------------------------------
12:17 p.m.
Am 17.06.2024 um 14:03 schrieb Riccardo (Jack) Lucchetti:
On 17/06/2024 12:54, Sven Schreiber wrote:
> But still a histogram certainly has its role. The doc for the
> relevant 'freq' command mentions that the numerical histogram can be
> accessed via $result. I guess that can be used (in a loop) to
> construct the needed plot with your gnuplot magic. Right now I don't
> have time to look into this further.
Up to a point, I'm afraid: the $result for continuous data gives you
the midpoint, but not the boundaries of the bin. And these can be
different from variable to variable, so that'd be tricky.
Yes; however, you can set a uniform pattern with --min=... and
--bindwidth=....
I'd argue that if you want a histogram and not a smoothed density, then
it makes sense to use the same bins when you plan to plot them together.
The first plot example with R in the link given by Chris also does this,
I think. Of course, you still need an algorithm to set a sensible min
and width value.
> (Apart from the other thing that is mentioned in the freq doc, namely
> that the aggregate() function can be used. That's certainly true, but
> it doesn't give an example of how exactly. A challenge for you!?)
open mroz87.gdt
eval aggregate(const, WE)
Well, this is again a discrete frequency distribution, not a histogram.
Maybe the freq help implicitly only has the discrete case in mind.
thanks
sven
4:56 p.m.
Many thanks, Sven and Riccardo. You have given me much to work with.
The data I am working with is indeed discrete.
One of the two series has a fairly tight standard deviation, and the other does not.
This does bring about an issue that I believe Riccardo mentioned: the number of
"bins" for both. If I choose the same number of bins, but one series has a much
tighter standard deviation, then overlaying the two will look odd, since the frequency
distribution which is tighter will have much smaller bins, resulting in a picture with two
sets of bin sizes. I played around with the R version of this and saw that in order to get
the bins to look uniform in size, I'd have to choose only two or three bins (R command
for this is "breaks") for the tighter variables and upwards of 52 bins for the
more volatile series.
I'm guessing there's a nice relationship that can be formalized where you can pick
the number of bins for one series and the second series' number of bins should then be
a function of the first series' standard deviation.
186
days inactive
188
days old
11 comments
3 participants
participants (3)
-
climnios＠providence.edu -
Riccardo (Jack) Lucchetti -
Sven Schreiber